实例1分级标题栏
第12、13、14讲代码
查看模式编辑模式万物之源ACCESS
第12、13、14讲
代码
Option Explicit
Dim con As ADODB.Connection '声明连接对象变量
Dim rs As ADODB.Recordset '声明记录集对象变量
'释放变量空间、关闭数据库连接、关闭窗体
Private Sub cmdClose_Click()
con.Close
Set rs = Nothing
Set con = Nothing
Unload Me
End Sub
'鼠标选择某个部门，相当于单击列表框，单击列表框，查询所选部门的员工
'提取员工的编号和姓名，避免姓名重复的问题
Private Sub lstBM_Click()
Dim sql As String, i As Integer
sql = "select 编号,姓名 from 员工 where 部门='" & lstBM.Value & "' order by 编号"
rs.Open sql, con, adOpenKeyset, adLockOptimistic
With lstEmp
.Clear
For i = 1 To rs.RecordCount
.AddItem rs("编号") & Space(2) & rs("姓名") 'space(n)，用于产生n个空格
rs.MoveNext
Next i
End With
rs.Close
End Sub
Private Sub lstEmp_Click()
Dim arr, i As Integer
Dim sql As String
sql = "select * from 员工 where 编号='" & Left(lstEmp.Value, 6) & "'"
rs.Open sql, con, adOpenKeyset, adLockOptimistic
'将每个字段的值存到相应的控件里
arr = Array("txtID", "txtName", "txtNumber", "txtBM", "txtAge", _
"txtZW", "txtDate", "txtAddress", "txtMail", "txtInfo")
For i = 0 To UBound(arr)
Me.Controls(arr(i)).Value = rs.Fields(i)
Next i
rs.Close
End Sub
'当窗体加载时，填写lstBM这个列表框的内容
Private Sub UserForm_Initialize()
'建立数据库的连接
Set con = New ADODB.Connection
With con
.Provider = "microsoft.ace.oledb.12.0"
.ConnectionString = "data source=" & _
ThisWorkbook.Path & "\学生管理.accdb"
.Open
End With
'提取不重复的部门名称
Dim sql As String '定义命令字符串变量
sql = "select distinct 部门 from 员工"
Set rs = New ADODB.Recordset '创建记录集对象
rs.Open sql, con, adOpenKeyset, adLockOptimistic
'将记录集中的部门名称显示到lstBM列表框中
Dim i As Integer
With lstBM
.Clear
For i = 1 To rs.RecordCount
.AddItem rs("部门")
rs.MoveNext '将记录集中的指针指向下一条记录
Next i
End With
rs.Close
End Sub
